38

The vector field has a potential, namely $f(x,y) = x^2-3xy +\frac{4}{3}y^3$. The start and end points of the curve are the same (the curve is a closed curve). The work done is zero, as the potential at the start and end points are the same.

The code below graphs the curve along with the vector field, and then computes the work directly from the formula (without finding a potential). Remember that @ is used for function composition, where you need if the input is a vector, rather than a number. This is why we use F and r @, as the input to F is a vector, while the input to r is a number.

F[x_, y_] := {2 x - 3 y, -3 x + 4 y^2}
r[t_] := {3 Cos[t], 3 Sin[t]}
Show[
 VectorPlot[F[x, y], {x, -4, 4}, {y, -4, 4}], 
 ParametricPlot[r[t], {t, 0, 2 Pi}]
 ]
Integrate[Dot[F @@ r@t, D[r[t], t]], {t, 0, 2 Pi}]

We compute $\vec \nabla \times \vec F = (-4 + 5 x z, 3 y - 5 y z, -2 x - 3 z)$. This gives $\vec \nabla \cdot (\vec \nabla \times \vec F) = 5z+3-5z-3 = 0$. Provided a vector field is twice continuously differentiable, Task 5 has you show that the divergence of the curl of a vector field is always zero.

With Mathematica, here's the code for this example.

F[x_, y_, z_] := {2 x + 3 y z, 4 z - x^2, 5 x y z}
Curl[F[x, y, z], {x, y, z}]
Div[%, {x, y, z}]

The partial derivatives are $$\frac{\partial \vec r}{\partial u} = (1,0,-2u),\quad \frac{\partial \vec r}{\partial v} = (0,1,-2v), $$ The normal vector $\vec n$ is the cross product of these two, so $$\vec n = (2u, 2v,1).$$

r[u_, v_] := {u, v, 1 - u^2 - v^2}
D[r[u, v], u]
D[r[u, v], v]
Cross[D[r[u, v], u], D[r[u, v], v]]

The area of a small parallelogram on the surface formed by $$\frac{\partial \vec r}{\partial u}du = (1,0,-2u)du\quad \text{and}\quad \frac{\partial \vec r}{\partial v}dv = (0,1,-2v)dv$$ is the magnitude of their cross product. The cross product of these two vectors is $$\vec n = (2u, 2v,1)dudv.$$ The magnitude of $\vec n$ gives a small bit of surface area as $$d\sigma = \sqrt{4u^2+4v^2+1}dudv.$$ The total surface area is the given by the sum of small bits of surface area. $$\sigma = \iint_S d\sigma = \int_{0}^{1}\int_{-1}^{1}\sqrt{4u^2+4v^2+1}dvdu.$$

r[u_, v_] := {u, v, 1 - u^2 - v^2}
n = Cross[D[r[u, v], u], D[r[u, v], v]]
Norm[n] // ComplexExpand
Integrate[Norm[n], {u, -1, 1}, {v, 0, 1}]
% // N
ParametricPlot3D[r[u, v], {u, -1, 1}, {v, 0, 1}]

Task 4 has you examine surfaces to visualize the relationship between the partial derivatives, the normal vector, and little bits of surface area. Here's the last portion of Task 4, adapted to this surface.

Module[{r, u, v, ru, rv, n, uBounds, vBounds},
 r[u_, v_] := {u, v, 1 - u^2 - v^2};
 uBounds = {u, -1, 1};
 vBounds = {v, 0, 1};
 ru[u_, v_] := Derivative[1, 0][r][u, v];
 rv[u_, v_] := Derivative[0, 1][r][u, v];
 n[u_, v_] := Cross[ru[u, v], rv[u, v]];
 Manipulate[Show[
   ParametricPlot3D[r[u, v], uBounds, vBounds, PlotStyle -> Opacity[0.5]],
   Graphics3D[{Thick,
     Red, Arrow[{r[u1, v1], r[u1, v1] + ru[u1, v1]}],
     Blue, Arrow[{r[u1, v1], r[u1, v1] + rv[u1, v1]}], 
     Opacity[0.5], Green, Polygon[{r[u1, v1], r[u1, v1] + ru[u1, v1], r[u1, v1] + ru[u1, v1] + rv[u1, v1], r[u1, v1] + rv[u1, v1]}],
     Opacity[1], Black, Polygon[{r[u1, v1], r[u1, v1] + ru[u1, v1] du, r[u1, v1] + ru[u1, v1] du + rv[u1, v1] dv, r[u1, v1] + rv[u1, v1] dv}]}],
   PlotRange -> All, ImageSize -> Large],
  {{u1, (uBounds[[2]] + uBounds[[3]])/2}, uBounds[[2]], uBounds[[3]]},
  {{v1, (vBounds[[2]] + vBounds[[3]])/2}, vBounds[[2]], vBounds[[3]]},
  {{du, 0.5}, 0, 1},
  {{dv, 0.5}, 0, 1}
  ]]

The vector field has a potential as the derivative $D\vec F =\begin{bmatrix}- &2x \\2x &-\end{bmatrix}$ is symmetric.

• A potential for the vector field is $f(x,y) = 2x^2+x^2y+y^2$ (note $\int 4x+2xy dx = 2x^2+x^2y +C(y)$ and $\int x^2+2y dy = x^2y+y^2+D(x)$).
• The start point is $\vec r(0) = (-1,2)$ and the end point is $\vec r(1) = (2,-3)$.

The work done by $\vec F$ is the difference in potential, which gives $$\int_C\vec F\cdot d\vec r = f(2,-3) - f(-1,2)=(8-12+9)-(2+2+4) = 5-8 = - 3.$$