20241202

All of the computations above are related to the same surface.

The surface is a cone whose axis of symmetry is on the $z$-axis.

r[u_, v_] := {u Cos[v], u Sin[v], u}
uB = {u, 0, 3}
vB = {v, 0, 2 Pi}
surfaceplot = ParametricPlot3D[r[u, v], uB, vB, PlotStyle -> Opacity[0.5]]

To compute the surface area, we first need $$\vec n = \vec r_u\times \vec r_v = (-u\cos v, -u\sin v, u )$$

ru = D[r[u, v], u]
rv = D[r[u, v], v]
n = Cross[ru, rv] // Simplify

The magnitude of this vector gives $dS = u\sqrt{2}dudv$.

Norm[n]

The surface area is hence $$ \int_{0}^{2\pi}\int_{0}^{3} u\sqrt{2}dudv = 9\sqrt 2 \pi.$$

Integrate[Norm[n], uB, vB]

Notice that the density can be written as $\delta = u^2$. We then have $$\bar z = \frac{\int_{0}^{2\pi}\int_{0}^{3} (u)(u^2)u\sqrt{2}dudv}{\int_{0}^{2\pi}\int_{0}^{3} u^2u\sqrt{2}dudv} = \frac{12}{5}.$$

Integrate[u u^2 Norm[n], uB, vB]/Integrate[u^2 Norm[n], uB, vB]

As a quick check, notice that 12/5 = 2.4 is between 0 and 3, so the answer makes physical sense.

The flux problem is just more substitution, with one additional question to address. We must determine whether $\vec n$ points towards the $z$-axis or away from the $z$-axis. This can be done in many ways (we'll use Mathematica below). For this particular problem, note that the $z$-component of $\vec n$ is positive. The only way the normal vector to this particular surface can have a positive $z$-component is if the vector points inwards. As such, we need to use $-\vec n$ for the flux computation. We can then set up the flux integral as $$\Phi = \iint_S \vec F\cdot (-\vec n)dudv =\int_{0}^{2\pi}\int_{0}^{3} (2 (u\cos v) + 3 (u\sin v)(u), (u\cos v)^2 u\sin v, -u (u\sin v)^2)\cdot(-(-u\cos v, -u\sin v, u ))dudv =\frac{315\pi}{4} .$$ The work below uses Mathematica to illustrate everything we just computed.

F[x_, y_, z_] := {2 x + 3 y z, x^2 y, -z y^2}

(*Save the surface as a region for use in the SliceVectorPlot function*)
surface = ParametricRegion[r[u, v], Evaluate[{uB, vB}]]
vectorfieldplot = SliceVectorPlot3D[F[x, y, z], surface, {x, -3, 3}, {y, -3, 3}, {z, -3, 3}, VectorMarkers -> Placed["Arrow3D", "Start"]]

(*Add normal vectors to the surface pointing in the direction of n*)
Show[surfaceplot, vectorfieldplot,
 Graphics3D[Table[Arrow[{r[u, v], r[u, v] + n/Norm[n]}], {u, 1, 3, .5}, {v, 0, 2 Pi, Pi/4}]],
 PlotRange -> All
 ]
Integrate[F @@ r[u, v] . n, uB, vB]

(*Add normal vectors to the surface pointing in the direction of -n*)
Show[surfaceplot, vectorfieldplot,
 Graphics3D[Table[Arrow[{r[u, v], r[u, v] + -n/Norm[n]}], {u, 1, 3, .5}, {v, 0, 2 Pi, Pi/4}]],
 PlotRange -> All
 ]
Integrate[F @@ r[u, v] . -n, uB, vB]