Brain Gains (Rapid Recall, Jivin' Generation)

  • For the vector field $\vec F(x,y) = (x+y, x^2)$ state $M$ and $N$.

Solution

The notation we'll be using is $\vec F(x,y)=(M,N)$ or $\vec F(x,y,z) = (M,N,P)$. This gives

  • $M=x+y$
  • $N=x^2$.

With Mathematica, when we've already defined $\vec F$, we can use the following to get the components. Note that because N[] is already defined as a Mathematica function, we have to use different notation for the name of the function. 

F[x_, y_] := {x + y, x^2}
M[x_, y_] := F[x, y][[1]]
Nn[x_, y_] := F[x, y][[2]]
F[x, y]
M[x, y]
Nn[x, y]
  • For the curve $\vec r(t) = (t^2, t^3)$, state $x$, $y$, $dx$, $dy$, and $ds$ in terms of $t$.

Solution

We have

  • $x = t^2$
  • $y = t^3$
  • $dx=2t dt$ (the differential of $x$ equals $2t$ multiplied by the differential of $t$. )
  • $dy=3t^2 dt$ (the $dt$ here matters. We have $\frac{dy}{dt} = 3t^2$, and we have $dy=3t^2 dt$.)
  • $ds = \sqrt{(2t)^2+(3t^2)^2}dt$ - This is the quantity we use for arc length.

Note that $dx$ is the differential of $x$, whereas $\frac{dx}{dt}$ is the derivative of $x$ with respect to $t$.

Here's an option for defining all these values in Mathematica. The ClearAll[] command is used to make sure that any previous definitions given for any of these variables are removed from memory. We'll start doing this from here on out, as it's good programming practice. 

ClearAll[x, y, dx, dy, dt, ds]
r[t_] := {t^2, t^3}
x[t_] := r[t][[1]]
y[t_] := r[t][[2]]
dx[t_, dt_] := x'[t] dt
dy[t_, dt_] := y'[t] dt
ds[t_, dt_] := Norm[r'[t]] dt
x[t]
y[t]
dx[t, dt]
dy[t, dt]
ds[t, dt]
ds[t, dt] // ComplexExpand
  • Given $\vec F(x,y) = (x+y, x^2)$ and $\vec r(t) = (t^2, t^3)$ state $\vec F(\vec r(t))$.

Solution

Recall that $\vec r(t) = (t^2, t^3)$ means $x=t^2$ and $y=t^3$, so $$\vec F(\vec r(t)) = \vec F(x=t^2, y=t^3) = (t^2+t^3, (t^2)^2).$$

Function composition in Mathematica can be done with the At and Apply commands (using @ and ). The Apply[] command (using ) is needed with the output of a function is a vector (which is true for the vector-valued function $\vec r(t)$. 

ClearAll[F, r]
F[x_, y_] := {x + y, x^2}
r[t_] := {t^2, t^3}
F @@ r@t
F @@ r[t]
Apply[F, r[t]]
F[r[t]] (*Does not work because the output of r[t] is a vector*)
  • Set up the work integral $\int_C Mdx+Ndy$ for $\vec F(x,y) = (x+y, x^2)$ and $\vec r(t) = (t^2, t^3)$ for $t\in [-1,3] $ (so replace each term with what it equals in terms of $t$).

Solution

We have the following:

  • $M=x+y = t^2+t^3$,
  • $N=x^2 = (t^2)^2$,
  • $dx = 2tdt$,
  • $dy = 3t^2dt$.

This gives $$\int_C Mdx+Ndy =\int_{-1}^3 \underbrace{(t^2+t^3)}_{M}\underbrace{(2tdt)}_{dx}+\underbrace{(t^2)^2}_{N}\underbrace{(3t^2dt)}_{dy} .$$ 

ClearAll[F, r]
F[x_, y_] := {x + y, x^2}
r[t_] := {t^2, t^3}
F @@ r[t]
r'[t]
(F @@ r[t]) . r'[t]
Integrate[(F @@ r[t]) . r'[t], {t, -1, 3}]
  • Set up the work integral $\int_C \vec F\cdot d\vec r$ for $\vec F(x,y) = (3xy, x+2y)$ and $\vec r(t) = (t^2+1, 2t)$ for $t\in [0,2] $.

Solution

We have the following:

  • $F(\vec r(t)) = (3(t^2+1)(2t), (t^2+1)+2(2t))$,
  • $\frac{d\vec r}{dt}=(2t,2)$,
  • $d\vec r=(2t,2)dt$.

This gives $$\int_C \vec F\cdot d\vec r =\int_{0}^2 \left[\underbrace{(3(t^2+1)(2t))}_{M}\underbrace{(2t)}_{dx/dt}+\underbrace{((t^2+1)+2(2t))}_{N}\underbrace{(2)}_{dy/dt}\right]dt .$$ 

ClearAll[F, r]
F[x_, y_] := {3 x y, x + 2 y}
r[t_] := {t^2 + 1, 2 t}
F @@ r[t]
r'[t]
(F @@ r[t]) . r'[t]
Integrate[(F @@ r[t]) . r'[t], {t, 0, 2}]

Group Problems

  1. Use the arc length formula and the parameterization $\vec r(t)=(a\cos t,a\sin t)$ of a circle to verify that the circumference of a circle of radius $a$ is $2\pi a$. $$s=\int_?^? \sqrt{(?)^2+(?)^2}dt.$$
  2. A force given by $\vec F = (y,-x+y)$ acts on an object as it moves along the curve $\vec r(t) =(t,t^2)$ for $0\leq t\leq 2$. Note that this means $x=t$ and $y=t^2$, so $\vec F = (t^2,-t+t^2)$. Compute $\ds \int_C\vec F\cdot \frac{d\vec r}{dt}dt$ (the work done by the force along the curve).
  3. Consider the curve $C$ parametrized by $\vec r(t) = (t, t^2)$ for $0\leq t\leq 2$.
    • Give a vector equation of the tangent line to the curve at $t=1$ (fill in the blanks below): $$\begin{pmatrix}?\\?\end{pmatrix} = \begin{pmatrix}?\\?\end{pmatrix}t+\begin{pmatrix}?\\?\end{pmatrix}.$$
    • Set up an integral that gives the length of this curve. Just set it up (fill in the blanks below). $$s=\int_?^? \sqrt{(?)^2+(?)^2}dt.$$